13.09.2023 18:20
[#1]
Program do hurtowego tworzenia ikon
Zna ktos jakis program/skrypt do hurtowego utworzenia ikon do wszystkich podkatalogów np w danym katalogu. Przeniosłem sobie dane z jednej karty na drugą i wiele ikon się zgubiło. Musze teraz klikać show all files, zeby widziec te katalogi.
14.09.2023 00:29
[wyróżniony]
[#4]
Re: Program do hurtowego tworzenia ikon
@moulder, post #1
Użyj CopyIcon44. Po uruchomieniu programu do lewego okienka wrzuć ikonkę jaką chcesz aby została utworzona dla Twoich katalogów. Do prawego okienka przeciągnij wcześniej zaznaczone katalogi.
15.09.2023 16:31
[wyróżniony]
[#8]
Re: Program do hurtowego tworzenia ikon
@moulder, post #1
Zmajstrowałem dla Ciebie taki skrypcik. Do prawidłowego dizłania wymaga FirstLine oraz GetSize. Generalnie u mnie działa prawidłowo, wybieram ikonę źródłową, następnie miejsce docelowe z katalogami. Niestety skrypt nie zagłębia się w strukturę katalogów. Nie mam również pewności co się stanie gdy nie wybierzesz żadnej ikonki lub katalogu docelowego. Co prawda czuwa nad tym polecenie GetSize, ale nigdy nic nie wiadomo.
Ostatnia aktualizacja: 15.09.2023 16:35:56 przez Ponki1986
; $VER: Add Icon 2 Drawers 1.0 (15.09.2023)
IF NOT EXISTS C:FIRSTLINE
SKIP ERRORX
ENDIF
IF NOT EXISTS C:GETSIZE
SKIP ERRORX
ENDIF
CD RAM:
REQUESTFILE >ENV:ICON PATTERN=#?.info DRAWER=RAM: PUBSCREEN=Workbench TITLE="Wybierz ikonkę źródłową."
GETSIZE >ENV:SIZE FILES TERSE ENV:ICON
IF "$SIZE" EQ "0"
SKIP ERROR
ENDIF
REQUESTFILE >ENV:DEST DRAWERSONLY DRAWER=RAM: PUBSCREEN=Workbench TITLE="Wskaż katalog docelowy."
GETSIZE >ENV:SIZE FILES TERSE ENV:DEST
IF "$SIZE" EQ "0"
SKIP ERROR
ENDIF
CD "$DEST"
C:LIST "$DEST" DIRS >RAM:LIST LFORMAT "%s"
LAB START
GETSIZE >ENV:SIZE FILES TERSE RAM:LIST
IF "$SIZE" EQ "0"
SKIP ERROR
ENDIF
IF "$SIZE" EQ "1"
SKIP ERROR
ENDIF
FIRSTLINE RAM:LIST >ENV:NAME DELETE
COPY >NIL: "$ICON" TO "$NAME.info"
SKIP BACK START
LAB ERROR
REQUESTCHOICE >NIL: TITLE="AddIcon2Drawers" BODY="Proces zakończony." GADGETS="OK"
DELETE >NIL: RAM:LIST ENV:SIZE ENV:DIR ENV:NAME ENV:DEST ENV:RQ
ENDCLI
LAB ERRORX
C:REQUESTCHOICE >NIL: TITLE="AddIcon2Drawers" BODY="W katalogu C: brakuje któregoś z poleceń:*n*n- GetSize*n- FirstLine*n*nDalsze działanie skryptu zostało przerwane." GADGETS="OK"
ENDCLI
Ostatnia aktualizacja: 15.09.2023 16:35:56 przez Ponki1986
